/* A simple macro select all or most ROIs
	v230817: 1st version   Peter J. Lee, Florida State University
*/
	macroL = "Select_All_ROIs_v230817b.ijm";
	nROIs = roiManager("count");
	if (nROIs<2) exit("Multiple ROIs not found");
	selectedROIs = Array.getSequence(nROIs);
	roiSizes = newArray();
	roiGroups = newArray();
	for (i=0;i<nROIs;i++){
		roiManager("Select", i);
		roiSizes = Array.concat(roiSizes,Roi.size);
		roiGroups = Array.concat(roiGroups, Roi.getGroup);
	}
	sizeRank = Array.rankPositions(roiSizes);
	Array.getStatistics(roiSizes, minSize, maxSize, meanSize, stdDevSize);
	Array.getStatistics(roiGroups, minGroup, maxGroup, null, null);
	infoColor = "#0076B6";
	infoWarningColor = "#ff69b4";
	infoFontSize = 12;
	Dialog.create("More options: " + macroL);
		roiSizeInfo = "ROI sizes: min = " + minSize + ", max = " + maxSize + ", mean = " + meanSize + ", stdDev = " + stdDevSize;
		if (nROIs > 2) roiSizeInfo += "\n2nd largest ROI = " + roiSizes[sizeRank[nROIs-2]];
		Dialog.addMessage(roiSizeInfo,infoFontSize, infoColor);
		exclusionOptions = newArray("First","Last");
		exclusionSizeOptions = newArray("Smallest","Largest");
		if (selectedROIs[0]==sizeRank[0]) exclusionOptions[0] = "First \(also Smallest\)";
		else if (selectedROIs[nROIs-1]==sizeRank[0]) exclusionOptions[1] = "Last \(also  Smallest\)";
		else exclusionOptions = Array.concat(exclusionOptions,"Smallest");
		if (selectedROIs[0]==sizeRank[nROIs-1]) exclusionOptions[0] = "First \(also Largest\)";
		else if (selectedROIs[nROIs-1]==sizeRank[nROIs-1]) exclusionOptions[1] = "Last \(also Largest\)";
		else exclusionOptions = Array.concat(exclusionOptions,"Largest");
		exclusionOptionChecks = Array.fill(Array.getSequence(exclusionOptions.length),false);
		Dialog.addMessage("Exclude the following ROIs:");
		Dialog.setInsets(0, 20, 0);
		Dialog.addCheckboxGroup(1,4,exclusionOptions,exclusionOptionChecks);
		operations = newArray("No", "AND", "Combine","XOR");
		operationInfo = "AND: Conjunction \(ROI overlaps only\)";
		operationInfo += "\nCombine: Union \(all ROI areas combined\)";
		operationInfo += "\nXOR: 'Exclusive or' \(in ROIs but excludes overlaps\)";
		Dialog.addRadioButtonGroup("Operations on selected ROI set:",operations,1,3,"No");
		Dialog.addMessage("Operations:\n" + operationInfo,infoFontSize, infoColor);
		Dialog.addCheckbox("Add set as new ROI?",false);
		Dialog.addNumber("Set group number \(current range " + minGroup + " - " + maxGroup + "\)",-1,0,3,"Leave as '-1' for no change");
	Dialog.show();
		exclusions = newArray();
		for (i=0;i<exclusionOptions.length;i++)
			if (Dialog.getCheckbox()) exclusions = Array.concat(exclusions, exclusionOptions[i]);
		operation = Dialog.getRadioButton();
		addSet = Dialog.getCheckbox();
		setGroup = Dialog.getNumber();
	if (exclusions.length>0){
		iExclusions = newArray();
		for (i=0;i<exclusions.length;i++){
			if (startsWith(exclusions[i],"First")) iExclusions = Array.concat(iExclusions,0);
			else if (startsWith(exclusions[i],"Last")) iExclusions = Array.concat(iExclusions,nROIs-1);
			else if (startsWith(exclusions[i],"Smallest")) iExclusions = Array.concat(iExclusions,sizeRank[0]);
			else if (startsWith(exclusions[i],"Largest")) iExclusions = Array.concat(iExclusions,sizeRank[nROIs-1]);
		}
		for (i=0;i<iExclusions.length;i++) selectedROIs = Array.deleteValue(selectedROIs, iExclusions[i]);
	}
	roiManager("Deselect");
	roiManager("Select", selectedROIs);
	if (setGroup>=0) RoiManager.setGroup(setGroup);
	if (!startsWith(operation,"No")) roiManager(operation);
	if (addSet){
		roiManager("Add");
		roiManager("Select", nROIs);
		roiManager("Rename",operation + "_" + Roi.getName);
	}