macro "Clean up errors in skeleton" {
	/* Diagonals and trapped square block cleanup to ensure 4-way (fully) connected lines
		v200512 1st version PJL NHMFL
		v210727 Added dialog and a few more fixes  Updated functions: 5/16/2022 3:38 PM
		v220818 Removed restoreExit.
	*/
	macroL = "Clean_up_Skeleton_v220818.ijm";
	run("8-bit");
	if (!is("binary")) {
		binaryChoice = getBoolean("Binary image required; run threshold?");
		if(binaryChoice) {
			run("Threshold...");
			waitForUser("Threshold complete?");
		}
		else exit("Goodbye");
	}
	if (is("Inverting LUT")) run("Invert LUT");
	getStatistics(null, meanI, null, null, null, null);
	getDimensions(imageWidth, imageHeight, imageChannels, imageSlices, imageFrames);
	if (meanI < 128) blackSkel = false;
	else blackSkel = true;
	dFixes = 0; sFixes = 0;
	sPixels = 0; semiPixels = 0; dblWides = 0;
	if (checkForPlugin("morphology_collection")) morphMe = true;
	else morphMe = false;
	zoomOPC = 100*getZoom();
	getLocationAndSize(xW, yW, widthW, heightW);
	Dialog.create("Clean up imageJ skeleton: " + macroL);
		Dialog.addCheckbox("Fix broken diagonals?",true);
		Dialog.addCheckbox("Fix trapped pixel squares?",true);
		Dialog.addCheckbox("Fill single pixel objects?",false);
		Dialog.addCheckbox("Fill diagonal-pixel trapped single pixel objects?",true);
		Dialog.addCheckbox("Fix most 2-pixel wide connections?",true);
		if (morphMe) Dialog.addNumber("Post-cleanup skeletonization? \(0 = No, -1 = Erode until idempotence\)", -1);
		Dialog.addCheckbox("Apply to copy of image or current selection?",true);
		Dialog.addCheckbox("Output fix report to log window?",false)
	Dialog.show();
		diags = Dialog.getCheckbox();
		pixies = Dialog.getCheckbox();
		sPixel = Dialog.getCheckbox();
		semiPixel = Dialog.getCheckbox();
		dblWide = Dialog.getCheckbox();
		if (morphMe){
			erosions = Dialog.getNumber();
			if (erosions==0) morphMe = false;
		}
		if(Dialog.getCheckbox()){
			run("Duplicate...", " ");
			xW +=20; xY +=20;
			run("Set... ", "zoom=&zoomOPC x=&xW y=&xY");
		}
		reportL = Dialog.getCheckbox;
	setBatchMode(true);
	if (blackSkel) run("Invert");
	if (sPixel || semiPixel || dblWide){
		for(i = 1; i<imageWidth-2; i++) { /* start 2nd column, end penultimate but one column */
			showStatus("Filling single pixel objects: " + sPixels + ", semi-trapped fills: " + semiPixels);
			showProgress(i, imageWidth-1);
			for(j = 1; j<imageHeight-3; j++) { /* start 2nd row, end penultimate but two row */
				coreInt = getPixel(i,j);
				if (coreInt==0) coreOpen = true;
				else coreOpen = false;
				skelN = 0;
				diagN = 0;
				for(k = -1; k<2; k++){
					for(l = -1; l<2; l++){
						pixInt = getPixel(i+k,j+l);
						if (pixInt==255) skelN++;
						if (k!=0 && l!=0 && pixInt==0) diagN++;
					}
				}
				if (coreOpen && sPixel && skelN==8){
					setPixel(i,j,255);
					sPixels++;
				}
				else if (coreOpen && semiPixel && skelN==7 && diagN==1){ 
					setPixel(i,j,255);
					semiPixels++;
				}
				else if (!coreOpen && dblWide && skelN>=6){
					mCount = 0;
					for (m=-1; m<2; m++) if (getPixel(i-1,j+m)==255) mCount++;
					if (mCount==3) setPixel(i-1,j,0);
					else {
						mCount = 0;
						for (m=-1; m<2; m++) if (getPixel(i+m,j-1)==255) mCount++;
						if (mCount==3){
							setPixel(i,j-1,0);
							dblWides++;
						} else { for (m=-1; m<2; m++) if (getPixel(i+m,j+1)==255) mCount++;
							if (mCount==3){
								setPixel(i,j+1,0);
								dblWides++;
								}else { for (m=-1; m<2; m++) if (getPixel(i+1,j+m)==255) mCount++;
								if (mCount==3){
									setPixel(i+1,j,0);
									dblWides++;
								}
							}
						}
					}
				}
			}
		}
	}
	/* 1st cleanup diagonals */
	if (diags){
		for(i = 1; i<imageWidth-1; i++) { /* start 2nd column, end penultimate column */
			showStatus("Fixing broken diagonals: " + dFixes + " fixes");
			showProgress(i, imageWidth-1);
			for(j = 0; j<imageHeight-1; j++) { /* start 1st row, end penultimate row */
				if ((getPixel(i,j))==255) {
					if ((getPixel(i+1,j))==0){ if((getPixel(i,j+1))==0){ if((getPixel(i+1,j+1))==255) {
						setPixel(i+1,j,255);
						dFixes += 1;
					}}} /* conditions end iteration at first exception */ 
					/* assume right and left fill-ins will balance out */
					if ((getPixel(i-1,j))==0){ if((getPixel(i,j+1))==0){ if((getPixel(i-1,j+1))==255) {
						setPixel(i-1,j,255);
						dFixes += 1;
					}}} /* conditions end iteration at first exception */ 
				}
			}
		}
	}
	if (pixies){
		for(i = 1; i<imageWidth-2; i++) { /* start 2nd column, end penultimate but one column */
			showStatus("Fixing trapped squares: " + sFixes + " fixes");
			showProgress(i, imageWidth-1);
			for(j = 1; j<imageHeight-3; j++) { /* start 2nd row, end penultimate but two row */
				if ((getPixel(i,j))==255) {
					if ((getPixel(i+1,j))==255){ if((getPixel(i+2,j))==255){ if((getPixel(i,j+1))==255){ if((getPixel(i+1,j+1))==255){ if((getPixel(i+2,j+1))==255){
						if ((getPixel(i,j+2))==255){ if((getPixel(i+1,j+2))==255){ if((getPixel(i+2,j+2))==255){ /* trapped square */
						if ((getPixel(i+1,j-1))==0) {
							setPixel(i+1,j,0);
							sFixes += 1;
						}
						if ((getPixel(i+1,j+3))==0){
							setPixel(i+1,j+2,0);
							sFixes += 1;
						}
					}}}}}}}} /* conditions end iteration at first exception */ 
				}
			}
		}
	}
	if (morphMe) run("BinaryThin2 ", "kernel_a='1 1 1 2 1 2 0 0 0 ' kernel_b='2 1 1 0 1 1 0 0 2 ' rotations='rotate 45' iterations=&erosions white");
	if (blackSkel) run("Invert");
	setBatchMode("exit & display"); /* Probably not necessary if exiting gracefully but otherwise harmless */
	beep(); wait(300); beep(); wait(300); beep();
	call("java.lang.System.gc"); /* force a garbage collection */
	statusMessage = "Skeleton Cleanup Finished: " + dFixes + " diagonal and " + sFixes + " trapped square fixes";
	if (sPixels>0 || semiPixels>0){
		if (sPixels>0) statusMessage += ", " + sPixels + " single pixels";
		if (semiPixels>0) statusMessage += ", "+ semiPixels + " diagonally-trapped pixels";
		statusMessage += " filled";
		if (dblWides>0) statusMessage += ", "+ dblWides + " thick connectors thinned";
	}
	if (reportL){
		statusMessage = "" + macroL + " on " + getTitle() + ":\n" + statusMessage;
		print(statusMessage);
	showStatus(statusMessage);
}
	/*
		( 8(|)	( 8(|)	All ASC Functions	@@@@@:-)	@@@@@:-)
	*/
	function checkForPlugin(pluginName) {
		/* v161102 changed to true-false
			v180831 some cleanup
			v210429 Expandable array version
			v220510 Looks for both class and jar if no extension is given
			v220818 Mystery issue fixed, no longer requires restoreExit	*/
		pluginCheck = false;
		if (getDirectory("plugins") == "") print("Failure to find any plugins!");
		else {
			pluginDir = getDirectory("plugins");
			if (lastIndexOf(pluginName,".")==pluginName.length-1) pluginName = substring(pluginName,0,pluginName.length-1);
			pExts = newArray(".jar",".class");
			knownExt = false;
			for (j=0; j<lengthOf(pExts); j++) if(endsWith(pluginName,pExts[j])) knownExt = true;
			pluginNameO = pluginName;
			for (j=0; j<lengthOf(pExts) && !pluginCheck; j++){
				if (!knownExt) pluginName = pluginName + pExts[j];
				if (File.exists(pluginDir + pluginName)) {
					pluginCheck = true;
					showStatus(pluginName + "found in: "  + pluginDir);
				}
				else {
					pluginList = getFileList(pluginDir);
					subFolderList = newArray;
					for (i=0,subFolderCount=0; i<lengthOf(pluginList); i++) {
						if (endsWith(pluginList[i], "/")) {
							subFolderList[subFolderCount] = pluginList[i];
							subFolderCount++;
						}
					}
					for (i=0; i<lengthOf(subFolderList); i++) {
						if (File.exists(pluginDir + subFolderList[i] +  "\\" + pluginName)) {
							pluginCheck = true;
							showStatus(pluginName + " found in: " + pluginDir + subFolderList[i]);
							i = lengthOf(subFolderList);
						}
					}
				}
			}
		}
		return pluginCheck;
	}