macro "Image-stitch manual helper" {
/*	Allows for manual control if image-stitching by point pairs.
	v231114:	1st working version, Peter J. Lee Applied Superconductivity Center, Florida State University
		based on Images_to_Stack_Plus_v231113.ijm"
	v231115: Completed saved lines code. Fixed error on common name loop.
	v231116: More consistent variable names and addition of fully overlapping frames.
	v231127: Removed "!" from intermediate showStatus command to allow getLine, makeLine and run("SelectNone") selectWindow to work reliably. F1: Updated safeSaveAndClose
*/
	macroL = "Image-Stitch_Manual_Helper_v231127a-f1.ijm";
	ascPrefsKey = "asc.ImageStitchManualHelper.Prefs.";
	close("temp_*"); /* Cleanup if crashed last time */
	saveSettings();
	if (nImages<2)
		exit("Need more than one open image to stitch");
	imageList = removeDuplicatesInArray(getList("image.titles"), true);
	imageN = lengthOf(imageList);
	minTL = imageList[0].length;
	for (i=1; i<imageN; i++) minTL = minOf(minTL, imageList[0].length); /* Determine the minimum title length */
	for (i=1, isCommon=true; i<minTL-1 && isCommon; i++){
		commonName = substring(imageList[0], 0, i+1);
		for (j=0; j<imageN-1 && isCommon; j++)
			if (commonName!=substring(imageList[j+1], 0, i+1)) isCommon = false;
	}
	commonName = substring(commonName, 0, commonName.length-1);
	commonL = commonName.length;
	imageShortList = Array.copy(imageList);
	for (i=0; i<imageN; i++){
		if (indexOf(imageList[i], commonName)==0) imageShortList[i] = substring(imageList[i], commonL);
		imageShortList[i] = stripKnownExtensionFromString(imageShortList[i]);
	}
	bitD = bitDepth;
	if (!endsWith(commonName, "_") && !endsWith(commonName, "_")) mosaicName = commonName + "_Mosaic";
	else mosaicName = commonName + "Mosaic";
	/* If images are of different sizes the background color will be used to fill in the gaps, so for consistency the background is set to black */
	preBackground = Color.background;
	setBackgroundColor("black");
	preForeground = Color.foreground;
	setForegroundColor("white");
	marginPx = 0;
	/* ASC Dialog style */
	infoColor = "#006db0"; /* Honolulu blue */
	instructionColor = "#798541"; /* green_dark_modern (121,133,65) AKA Wasabi */
	infoWarningColor = "#ff69b4"; /* pink_modern AKA hot pink */
	infoFontSize = 12;
	Dialog.create("Select image order for stitching \(" + macroL + "\)");
		Dialog.addNumber("Limit to the first", imageN, 0, 5, "images listed");
		Dialog.addString("Mosaic name", mosaicName, mosaicName.length + 2);
		shortCommon = substring(commonName, 0, minOf(5, commonName.length)) + "...";
		if (imageN<30){
			Dialog.addMessage("Choose tile order, '1' will be the top tile. Alignment will be to the top tile", infoFontSize+1, instructionColor);
			for (i=0, addRow=0; i<imageN; i++, addRow++){
				if (addRow>0 && imageN>4){
					Dialog.addToSameRow();
					addRow = -1;
				}
				Dialog.addChoice("tile " + i+1 + " \(" + shortCommon + "\)", imageShortList, imageShortList[i]);
			}
		}
		else {
			Dialog.addChoice("Choose top tile \(1\)", imageList, imageList[0]);
			Dialog.addCheckbox("Set tile label as unique name as listed above", true);
		} 
		Dialog.setInsets(0, 20, 0);
		tileOptions = newArray("Reverse this order", "Manually crop montage", "Compute overlap", "Diagnostic mode");
		tileOptionChecks = newArray();
		tileOptionChecks = Array.concat(tileOptionChecks, call("ij.Prefs.get", ascPrefsKey + "reverseOrder", false));
		tileOptionChecks = Array.concat(tileOptionChecks, call("ij.Prefs.get", ascPrefsKey + "manCrop", false));
		tileOptionChecks = Array.concat(tileOptionChecks, call("ij.Prefs.get", ascPrefsKey + "computeOverlap", false));
		tileOptionChecks = Array.concat(tileOptionChecks, call("ij.Prefs.get", ascPrefsKey + "diagnostics", false));
		Dialog.addCheckboxGroup(1, 4, tileOptions, tileOptionChecks);
					manualAlignInfo = "Only vertical or horizontal strips are currently available in this test version."
				+ "\nIf a horizontal overlap is entered the series is assumed to be a horizontal tile set"
				+ "\nIf a vertical overlap is entered the series is assumed to be a vertical tile set";
		Dialog.addMessage(manualAlignInfo, infoFontSize,	instructionColor);
		Dialog.addNumber("Horizontal overlap", call("ij.Prefs.get", ascPrefsKey + "xOverlap", NaN), 1, 3, "%, leave blank for vertical strip");
		Dialog.addNumber("Vertical overlap", call("ij.Prefs.get", ascPrefsKey + "yOverlap", NaN), 1, 3, "%, leave blank for horizontal strip");
			/* Note that margins work for this manual alignment but IJ auto-alignment thinks that margins (any value including NaN) are dominant alignment features. */
	Dialog.show();
		tileN = Dialog.getNumber();
		mosaicName = Dialog.getString();
		tilesOrdered = newArray();
		tilesShortOrdered = newArray();
		if (imageN<30){
			for (i=0; i<tileN; i++){
				shortSliceName = Dialog.getChoice();
				tilesShortOrdered = Array.concat(tilesShortOrdered, shortSliceName);
				tilesOrdered = Array.concat(tilesOrdered, imageList[indexOfArray(imageShortList, shortSliceName, -1)]);
			}
		}
		else {
			tileZero = Dialog.getChoice();
			if (tileZero==imageList[0]) tilesOrdered = imageList;
			else if (tileZero==imageList[imageN-1]) tilesOrdered = Array.reverse(imageList);
			else {
				tilesOrdered = Array.concat(tileZero, imageList);
				tilesOrdered = removeDuplicatesInArray(tilesOrdered, false);
			}
			tilesOrdered = Array.trim(tilesOrdered, tileN);
			for (i=0; i<tilesOrdered.length; i++)
				tilesShortOrdered[i] = substring(tilesOrdered[i], commonL);
		}
		if (Dialog.getCheckbox()){
			tilesOrdered = Array.reverse(tilesOrdered);
			tilesShortOrdered = Array.reverse(tilesShortOrdered);
			reverseOrder = true;
		}
		else reverseOrder = false;
		call("ij.Prefs.set", ascPrefsKey + "reverseOrder", reverseOrder);
		manCrop =  Dialog.getCheckbox();
		call("ij.Prefs.set", ascPrefsKey + "manCrop", manCrop);
		computeOverlap = Dialog.getCheckbox();
		call("ij.Prefs.set", ascPrefsKey + "computeOverlap", computeOverlap);
		if (computeOverlap) computeOverlap = " compute_overlap";
		else computeOverlap = " ";
		diagnostics = Dialog.getCheckbox();
		call("ij.Prefs.set", ascPrefsKey + "diagnostics", diagnostics);
		xOverlap = Dialog.getNumber();
		yOverlap = Dialog.getNumber();
		call("ij.Prefs.set", ascPrefsKey + "xOverlap", xOverlap);
		call("ij.Prefs.set", ascPrefsKey + "yOverlap", yOverlap);
		if (isNaN(xOverlap)) xOverlap = 0;
		if (isNaN(yOverlap)) yOverlap = 0;
		yTile = false;
		xTile = false;
		zTile = false;
		if (yOverlap==0 && xOverlap==0) zTile = true;
		else if (yOverlap!=0 & xOverlap!=0){
			zTile = true;
			IJ.log("XY Mosaics are currently not handled and this entry: x overlap = " + xOverlap ", y overlap = " + yOverlap " is treated as fully overlapping");
		}
		else if (yOverlap!=0){
			yTile = true;
			yOverlap /= 100;
			xOverlap = 0;
		}
		else {
			xTile = true;
			xOverlap /= 100;
			yOverlap = 0;
		}
		if (xTile) tileType = "Horizontal " + xOverlap + "-overlap strip";
		else if (yTile) tileType = "Vertical " + yOverlap + "-overlap strip";
		else tileType = "Z-stack with full overlap";
	Dialog.create("ImageJ stitching options \(" + macroL + "\)");
		Dialog.addHelp("https://imagej.net/plugins/image-stitching");
		message = "Default options not set in this version: channels_for_registration=[Red, Green and Blue] rgb_order=rgb"
			+ "\n                  'subpixel_accuracy' and 'Save computation time' options will be used because why not?";
		Dialog.addMessage(message,infoFontSize,infoColor);
		blendingOptions = newArray("Linear Blending","Average","Median","Max. Intensity","Min. Intensity","Do not fuse images \(only write TileConfiguration\)");
		blendingTxt = "Blending Options: Linear blending: In the overlapping area the intensity are smoothly adjusted between the two images\n"
			+ "Average: In the overlapping area the average intensity between all images is computed (example source code)\n"
			+ "Median: In the overlapping area the median intensity of all images is computed\n"
			+ "Max. Intensity: In the overlapping area the maximum intensity between all images is used for the output image\n"
			+ "Min. Intensity: In the overlapping area the minimum intensity between all images is used for the output image\n"
			+ "Overlay into Composite: all channels of all input images will be put into the output image as separate channels\n"
			+ "Do not fuse images: no output images will be computed, just the overlap is computed";
		Dialog.addMessage(blendingTxt,infoFontSize-1,infoColor);
		blendingOption = call("ij.Prefs.get", ascPrefsKey+"blending","Linear Blending");
		Dialog.addChoice("Blending:",blendingOptions,blendingOption);
		// Dialog.addRadioButtonGroup("Blending:",blendingOptions,1,blendingOptions.length,blendingOptions[0]);
		Dialog.addNumber("Fusion value:",1.5,1,4,"1.5 default, no documentation, weird results >7");
		Dialog.addNumber("Regression value:",0.3,1,4,"Assumed non-overlapping if below this. 'Good' values are typically >0.7");
		Dialog.addNumber("max/avg:",3.5,1,4,"Default threshold error for discarding is 2.5");
		Dialog.addNumber("Absolute value:",3.5,1,4,"Links removed if the absolute displacement is greater \(default 3.5\)");
		fusionAreas = Array.resample(Array.getSequence(2), 11);
		Dialog.addRadioButtonGroup("Blended Area Fraction, TBH this doesn't seem to have much impact \(default is 0.2\):", fusionAreas, 1, 5, "0.2");
		if (is("grayscale")) isMonochrome = true;
		checkboxOptions = newArray("Copy 1st tile metadata to stitched image?","Decompose composite output");
		checkboxDefaults = newArray(true, true);
		if(getSliceNumber()>1){
			if (Stack.isHyperstack){
				hyper = true;
				checkboxOptions = Array.concat("Add tiles as ROIs?", checkboxOptions);
				checkboxDefaults = Array.concat(true, checkboxDefaults);
			} 
		}
		else hyper = false;
		colN = 2;
		rowN = Math.ceil(checkboxOptions.length/colN);
		Dialog.setInsets(5, 15, 0);
		Dialog.addCheckboxGroup(rowN, colN, checkboxOptions, checkboxDefaults);
		Dialog.addFile("Load previously saved line set", "");
	Dialog.show();
		blendingOption = Dialog.getChoice();
		call("ij.Prefs.set", ascPrefsKey+"blending", blendingOption);
		fusionVal = Dialog.getNumber();
		regressionVal = Dialog.getNumber();
		maxAvgVal = Dialog.getNumber();
		absVal = Dialog.getNumber();
		fusionFraction = Dialog.getRadioButton();
		bshScript = "mpicbg.stitching.fusion.BlendingPixelFusion.fractionBlended = " + fusionFraction;
		IJ.log("Temporary fractionBlend applied:")
		eval("bsh", bshScript);
		if (hyper) addROIs = Dialog.getCheckbox();
		else addROIs = false;
		transferMetadata = Dialog.getCheckbox();
		compoConvert = Dialog.getCheckbox();
		savedLinesFile = Dialog.getString();
		/* Currently only single-width strips are supported */
	/*  End of main dialog */
	gotLines = false;
	if (savedLinesFile!=""){
		if (File.exists(savedLinesFile)){
			savedLineSet = File.openAsString(savedLinesFile);
			savedLines = split(savedLineSet,"\n");
			if (lengthOf(savedLines)==2*(tileN-1)) gotLines = true;
			else IJ.log("Saved lines not used because " + lengthOf(savedLines) + "were found but " + 2*(tileN-1) + "are needed");
		}
	}
	call("ij.Prefs.set", ascPrefsKey + "lastImageStartWidth", Image.width);
	call("ij.Prefs.set", ascPrefsKey + "lastImageStartHeight", Image.height);
	tileNames = newArray;
	for (i=0; i<tileN; i++){
		tWOE = stripKnownExtensionFromString(tilesOrdered[i]);
		if (commonL>0 && commonL<tWOE.length) tWOE = substring(tWOE, commonL, tWOE.length);
		tileNames[i] = tWOE;
	}
	// if (isOpen(mosaicName)) close(mosaicName);
	if (!diagnostics) setBatchMode(true);
	preX = 0;
	preY = 0;
	lineCoords = "";
	for (i=0, sLines=0; i<tileN; i++){
		run("Cascade");
		setTool("line");
		imWidth = Image.width;
		imHt = Image.height;
		if (i==0){
			dir = getInfo("image.directory");
			thisTileConfig = tilesOrdered[i] + "; ; \(0.0, 0.0\)\n";
			tileConfig = thisTileConfig;
			tileConfigFP = "" + dir +  tileConfig;
			offsetX = 0;
			offsetY = 0;
		}
		else {
			while(getTitle!=tilesOrdered[i-1])	selectWindow(tilesOrdered[i-1]);
			tName = tilesShortOrdered[i-1];			
			setBatchMode("show");
			run("Main Window [enter]");
			run("View 100%");
			setLocation(0.05 * screenWidth, 0.15 * screenHeight, 0.4 * screenWidth, 0.8 * screenHeight);
			run("Scale to Fit");
			run("Select None");
			if (gotLines){
				restoredCoords = split(savedLines[sLines], ",");
				run("Select None");
				while (selectionType!=5)
					makeLine(parseInt(restoredCoords[0]), parseInt(restoredCoords[1]), parseInt(restoredCoords[2]), parseInt(restoredCoords[3]), 6);
				sLines++;
			}
			else if (xTile){
				x12 = imWidth * (1 - xOverlap / 2);
				run("Select None");
				while (selectionType!=5)
					makeLine(x12, 0.1 * imHt,  x12, 0.9 * imHt, 10);
			}
			else if (yTile){
				y12 = imHt * (1 - yOverlap / 2);
				run("Select None");
				while (selectionType!=5)
					makeLine(0.1 * imWidth, y12, 0.9 * imWidth, y12, 10); /* makeLine(x1, y1, x2, y2, lineWidth) */
			}
			else {
				run("Select None");
				while (selectionType!=5){
					if (i>2)  makeLine(x1, y1, x2, y2, 10);
					else makeLine(0.1 * imWidth,  0.1 * imHt, 0.9 * imWidth, 0.9 * imHt, 10);		
				}
			} 
			Roi.setStrokeColor("#50ff0000");
			Roi.setStrokeWidth(3);
			updateDisplay();
			showStatus("Target tile for alignment", "flash image red 1000ms");
			while (getTitle!=tilesOrdered[i]) selectWindow(tilesOrdered[i]);
			run("Main Window [enter]");
			sName = tilesShortOrdered[i];
			run("View 100%");
			run("Scale to Fit");
			setLocation(0.5 * screenWidth, 0.15 * screenHeight, 0.4 * screenWidth, 0.8 * screenHeight);
			showStatus("Source tile for alignment", "flash image cyan 1000ms");
			run("Select None");
			if (gotLines){
				restoredCoords = split(savedLines[sLines], ",");
				run("Select None");
				while (selectionType!=5)
					makeLine(parseInt(restoredCoords[0]), parseInt(restoredCoords[1]), parseInt(restoredCoords[2]), parseInt(restoredCoords[3]), 5);
				sLines++;
			}
			else if (xTile){
				x12 = imWidth * xOverlap / 2;
				run("Select None");
				while (selectionType!=5)
					makeLine(x12, 0.1 * imHt,  x12, 0.9 * imHt, 13);
			}
			else if (yTile){
				y12 = imHt * yOverlap / 2;
				run("Select None");
				while (selectionType!=5)
					makeLine(0.1 * imWidth, y12, 0.9 * imWidth, y12, 13); /* makeLine(x1, y1, x2, y2, lineWidth) */
			}
			else {
				run("Select None");
				while (selectionType!=5) { 
					if (i>2)  makeLine(x1, y1, x2, y2, 13);
					else makeLine(0.1 * imWidth,  0.1 * imHt, 0.9 * imWidth, 0.9 * imHt, 13);	
				}
			} 
			Roi.setStrokeColor("#5000ffff");
			Roi.setStrokeWidth(3);
			updateDisplay();
			hints = "\n  \nHint 1: Use the '+' and '-' keys to zoom in and out over the cursor for better accuracy\"
				+ "\nHint 2: You can quickly move the entire line by grabbing the center selection point"
				+ "\nHint 3: Switch between images using Window menu on ImageJ bar";
			lineInstructions =  "Adjust lines on target: " + tName + "\nand source: " + sName + "\nbetween the two well-spaced features" + hints;	
			waitForUser(tileType + ": set #" + i + ": Line Align Instructions", lineInstructions);
			while(getTitle!=tilesOrdered[i-1]) selectWindow(tilesOrdered[i-1]);
			getLine(x1, y1, x2, y2, lineWidth);
			lineCoords += "" + x1 + "," + y1 + "," + x2 + "," + y2 + "\n"; 
			cXT = (x1 + x2)/2;
			cYT = (y1 + y2)/2;
			run("Select None");
			run("Put Behind [tab]");
			while(getTitle!=tilesOrdered[i]) selectWindow(tilesOrdered[i]);
			getLine(x1, y1, x2, y2, lineWidth);
			lineCoords += "" + x1 + "," + y1 + "," + x2 + "," + y2 + "\n";
			cXS = (x1 + x2)/2;
			cYS = (y1 + y2)/2;
			run("Select None");
			offsetX += cXT - cXS;
			offsetY += cYT - cYS;
			thisTileConfig = tilesOrdered[i] + "; ; \(" + d2s(offsetX, 3) + ", " + d2s(offsetY, 3) + "\)";
			tileConfig += thisTileConfig;
			dir = getInfo("image.directory");
			tileConfigFP += "" + dir + thisTileConfig;
			if (i<tileN-1){
				tileConfig += "\n";
				tileConfigFP += "\n";
			} 
			if (diagnostics) IJ.log("Alignment " + i + ": source=" + sName + " target=" + tName + manualAlignOptionString);
		}
	}
	/* save line coordinates for future use */
	while (endsWith(lineCoords,"\n")) lineCoords = substring(lineCoords, 0, lineCoords.length-1);
	title1LineCoords = commonName + "_LineCoords";
  	title2LineCoords = "["+title1LineCoords+"]";
 	f = title2LineCoords;
  	if (isOpen(title1LineCoords))  print(f, "\\Update:"); // clears the window
  	else run("Text Window...", "name="+title2LineCoords+" width=72 height=8 menu");
	if (diagnostics) IJ.log("Full path tile configuration:\n" + lineCoords);
 	print(f, lineCoords);
	configLineCoordsPath = dir + title1LineCoords +".txt";
	saveAs("Text", configLineCoordsPath); /* Saved for compatibility with older versions */
	run("Close"); /* Need to close window and start fresh as there is no rename function for text windows */	
	/* end line saves */
	/* Create ImageJ-Stitch registration file */
	stitchHeader =  "# Define the number of dimensions we are working on\n"
				+ "dim = 2\n"
				+ "\n"
				+ "# Define the image coordinates\n";
	tileConfig = stitchHeader + tileConfig;
	tileConfigFP = stitchHeader + tileConfigFP;
	title1FP = commonName + "_Full-Path-TileConfiguration";
  	title2FP = "["+title1FP+"]";
 	f = title2FP;
  	if (isOpen(title1FP))  print(f, "\\Update:"); // clears the window
  	else run("Text Window...", "name="+title2FP+" width=72 height=8 menu");
	if (diagnostics) IJ.log("Full path tile configuration:\n" + tileConfigFP);
 	print(f, tileConfigFP);
	configFPPath = dir + title1FP +".txt";
	saveAs("Text", configFPPath); /* Saved for compatibility with older versions */
	run("Close"); /* Need to close window and start fresh as there is no rename function for text windows */
	title1 = commonName + "_TileConfiguration";
	title2 = "["+title1+"]";
	f = title2;
  	if (isOpen(title1)) print(f, "\\Update:"); // clears the window
  	else run("Text Window...", "name="+title2+" width=72 height=8 menu");
	if (diagnostics) IJ.log("Tile configuration:\n" + tileConfig);
	print(f, tileConfig);
	configPath = dir + title1 +".txt";
	saveAs("Text", configPath);
	run("Close");
	if (addROIs) optionROIs = " add_tiles_as_rois";
	else optionROIs = " ";
	stitchOptions = "type=[Positions from file] order=[Defined by TileConfiguration] directory=[&dir] layout_file="+title1+".txt fusion_method=[&blendingOption] fusion="+fusionVal+" regression_threshold="+regressionVal+" max/avg_displacement_threshold="+maxAvgVal+" absolute_displacement_threshold="+absVal+optionROIs+computeOverlap+ " ignore_z_stage subpixel_accuracy computation_parameters=[Save computation time (but use more RAM)] image_output=[Fuse and display]";
	run("Grid/Collection stitching", stitchOptions);
	if(diagnostics) IJ.log("Stitch commands:\n" + stitchOptions);
	nTitle = commonName + "_IJ-Stitch";
	if (!startsWith(blendingOption,"Do not")){
		waitForOpenWindow("Fused",500,1000,1000*tileN);
		selectWindow("Fused");
		rename(nTitle);
		if (bitDepth==24 && isMonochrome) run("8-bit");
		if (is("composite") && compoConvert){
			compoID = getImageID();
			if (is("grayscale") && grayConvert) run("Z Project...", "projection=[Average Intensity]");
			else run("Mosaic to RGB");
			convID = getImageID();
			selectImage(compoID);
			close();
			selectImage(convID);
		} 
		safeSaveAndClose("tiff", dir, nTitle + ".tif",false);
	}
	else IJ.log(macroL + " completed, 'Do not fuse' selected");
	if (is("Batch Mode")) setBatchMode("exit & display");
	call("java.lang.System.gc");
	run("Collect Garbage"); 
	// IJ.log("Stitch commands:\n" + stitchOptions);
	showStatus("Completed macro: " + macroL);
	if (manCrop){
		setBatchMode("exit and display");
		run("Select Bounding Box (guess background color)");
		setTool("rectangle");
		title = "Crop Mosaic";
		msg = "1. Select the area that you want to crop to. 2. Click on OK";
		waitForUser(title, msg);
		setBatchMode(true);
		if (selectionType>=0){
			run("Crop");
			run("Select None");
		}
	}
	run("Scale to Fit");
	setBatchMode("exit and display");
	Color.setBackground(preBackground);
	Color.setForeground(preForeground);
	restoreSettings();
	IJ.log("Completed " + macroL + ":\n" + mosaicName);
	showStatus(macroL + " completed", "flash green");
}
	/*
		   ( 8(|)	( 8(|)	Functions	@@@@@:-)	@@@@@:-)
   */
	function indexOfArray(array, value, default) {
		/* v190423 Adds "default" parameter (use -1 for backwards compatibility). Returns only first found value
			v230902 Limits default value to array size */
		index = minOf(lengthOf(array) - 1, default);
		for (i=0; i<lengthOf(array); i++){
			if (array[i]==value) {
				index = i;
				i = lengthOf(array);
			}
		}
	  return index;
	}
	function removeDuplicatesInArray(array, sortFlag) {
		/* v230822-3: 1st version.  Peter J. Lee FSU	*/
		if (lengthOf(array)<=1) return array;
		else {
			if (!sortFlag) arrayOrder = Array.rankPositions(array);
			sortedArray = Array.sort(array);
			for (i=0; i<lengthOf(sortedArray)-1; i++){
				if (sortedArray[i]==sortedArray[i+1]){
					sortedArray = Array.deleteIndex(sortedArray, i);
					if (!sortFlag) arrayOrder = Array.deleteIndex(arrayOrder, i);
					i -= 1;
				}
			}
			if (!sortFlag) Array.sort(arrayOrder, sortedArray);
			return sortedArray;
		}
	}
	function safeSaveAndClose(filetype, path, fileSaveName, closeImageIfSaved){
		/* v230411: 1st version reworked
			v230812: Uses full dialog which should save time for non-saves, includes options to change the directory and filetype.
			v230814: Close by imageID not filename. Added option to override closeImageIfSaved.
			v230915: Saves if there is no change in path rather than getting stuck in loop.
			v230920: Allows empty path string.
			v240315: Fixed RadioButton issue.
		*/
		functionL = "safeSaveAndClose_v240315";
		imageID = getImageID();
		fS = File.separator;
		filetypes = newArray("tiff", "png", "jpeg");
		extensions = newArray("tif", "png", "jpg");
		for (i=0; i<3; i++){
			if (filetype==filetypes[i]) extension = extensions[i];
			else extension = extensions[0];
		}
		if (!endsWith(fileSaveName, extension)){
			if (lastIndexOf(fileSaveName, ".")>fileSaveName.length-5) fileSaveName = substring(fileSaveName, 0, lastIndexOf(fileSaveName, ".")+1) + extension;
			else fileSaveName += "." + extension;
		}
		if (path!=""){
			if(endsWith(path, fS)) path = substring(path, 0, path.length-1);
			fullPath = path + fS + fileSaveName;
		}
		else fullPath = "";
		newSave = false;
		if (!File.exists(fullPath) && fullPath!=""){
			saveAs(filetype, fullPath);
			if (File.exists(fullPath)) newSave = true;
		}
		if (!newSave){
			Dialog.create("Options: " + functionL);
				if (path!=""){
					Dialog.addMessage("File: " + fileSaveName + " already exists in\n" + path);
					Dialog.addMessage("If no changes are made below, the existing file will be overwritten");
				}
				Dialog.addString("Change the filename?", fileSaveName, fileSaveName.length+5);
				if (path=="") path = File.directory;
				Dialog.addDirectory("Change the directory?", path);
				// Dialog.addChoice("Change the filetype?", filetypes, filetypes[0]);
				Dialog.addRadioButtonGroup("Change the filetype?", filetypes, 1, filetypes.length, filetypes[0]);
				Dialog.addCheckbox("Don't save file", false);
				Dialog.addCheckbox("Close image \(imageID: " + imageID + ") after successful save", closeImageIfSaved);
			Dialog.show;
				newFileSaveName = Dialog.getString();
				newPath = Dialog.getString();
				// newFiletype = Dialog.getChoice();
				newFiletype = Dialog.getRadioButton();
				dontSaveFile = Dialog.getCheckbox();
				closeImageIfSaved = Dialog.getCheckbox();
			if (!dontSaveFile){
				if (!File.isDirectory(newPath)) File.makeDirectory(newPath);
				if (!endsWith(newPath, fS)) newPath += fS;
				for (i=0; i<3; i++){
					if (newFiletype==filetypes[i]){
						newExtension = extensions[i];
						if (extension!=newExtension) newfileSaveName = replace(newFileSaveName, extension, newExtension);
					}
				}
				newFullPath = newPath + newFileSaveName;
				if (!File.exists(newFullPath) || newFullPath==fullPath) saveAs(newFiletype, newFullPath);
				else safeSaveAndClose(newFiletype, newPath, newFileSaveName, closeImageIfSaved);
				if (File.exists(newFullPath)) newSave = true;
			}
		}
		if (newSave && closeImageIfSaved && nImages>0){
			if (getImageID()==imageID) close();
			else IJ.log(functionL + ": Image ID change so fused image not closed");
		}
	}
	function stripKnownExtensionFromString(string) {
		/*	Note: Do not use on path as it may change the directory names
		v210924: Tries to make sure string stays as string.	v211014: Adds some additional cleanup.	v211025: fixes multiple 'known's issue.	v211101: Added ".Ext_" removal.
		v211104: Restricts cleanup to end of string to reduce risk of corrupting path.	v211112: Tries to fix trapped extension before channel listing. Adds xlsx extension.
		v220615: Tries to fix the fix for the trapped extensions ...	v230504: Protects directory path if included in string. Only removes doubled spaces and lines.
		v230505: Unwanted dupes replaced by unusefulCombos.	v230607: Quick fix for infinite loop on one of while statements.
		v230614: Added AVI.	v230905: Better fix for infinite loop. v230914: Added BMP and "_transp" and rearranged
		*/
		fS = File.separator;
		string = "" + string;
		protectedPathEnd = lastIndexOf(string,fS)+1;
		if (protectedPathEnd>0){
			protectedPath = substring(string,0,protectedPathEnd);
			string = substring(string,protectedPathEnd);
		}
		unusefulCombos = newArray("-", "_"," ");
		for (i=0; i<lengthOf(unusefulCombos); i++){
			for (j=0; j<lengthOf(unusefulCombos); j++){
				combo = unusefulCombos[i] + unusefulCombos[j];
				while (indexOf(string,combo)>=0) string = replace(string,combo,unusefulCombos[i]);
			}
		}
		if (lastIndexOf(string, ".")>0 || lastIndexOf(string, "_lzw")>0) {
			knownExts = newArray(".avi", ".csv", ".bmp", ".dsx", ".gif", ".jpg", ".jpeg", ".jp2", ".png", ".tif", ".txt", ".xlsx");
			knownExts = Array.concat(knownExts,knownExts,"_transp","_lzw");
			kEL = knownExts.length;
			for (i=0; i<kEL/2; i++) knownExts[i] = toUpperCase(knownExts[i]);
			chanLabels = newArray(" \(red\)"," \(green\)"," \(blue\)","\(red\)","\(green\)","\(blue\)");
			for (i=0,k=0; i<kEL; i++) {
				for (j=0; j<chanLabels.length; j++){ /* Looking for channel-label-trapped extensions */
					iChanLabels = lastIndexOf(string, chanLabels[j])-1;
					if (iChanLabels>0){
						preChan = substring(string,0,iChanLabels);
						postChan = substring(string,iChanLabels);
						while (indexOf(preChan,knownExts[i])>0){
							preChan = replace(preChan,knownExts[i],"");
							string =  preChan + postChan;
						}
					}
				}
				while (endsWith(string,knownExts[i])) string = "" + substring(string, 0, lastIndexOf(string, knownExts[i]));
			}
		}
		unwantedSuffixes = newArray(" ", "_","-");
		for (i=0; i<unwantedSuffixes.length; i++){
			while (endsWith(string,unwantedSuffixes[i])) string = substring(string,0,string.length-lengthOf(unwantedSuffixes[i])); /* cleanup previous suffix */
		}
		if (protectedPathEnd>0){
			if(!endsWith(protectedPath,fS)) protectedPath += fS;
			string = protectedPath + string;
		}
		return string;
	}
	function waitForOpenWindow(windowName, testWait, minWait, maxWait) {
		/* v230511: 1st version 
			v231114: Added fail status and return
		*/
		wait(minWait);
		maxIterations = maxWait/testWait;
		for (i=0; i<maxIterations; i++){
			showProgress(i, maxIterations);
			showStatus("Waiting for " + windowName);
			if (!isOpen(windowName)) wait(testWait);
			else i = maxIterations;
		}
		if (!isOpen(windowName)){
			showStatus("The wait for " + windowName + " is over");
			return true;
		} 
		else {
			showStatus("Gave up waiting for " + windowName);
			return false;
		}
	}