/* 
	# Overlay_Manager
	Very simple overlay selection manager: PJL NHMFL
	v180828:	1st version.
	v180829:	Added move.
	v190222:	Now shows slice number and does not restore old selections unless unless shown in original.
	v190222b:	Added wildcard delete string.
	v200130:	Shows only ranges of overlays to better handle long lists.
	v230221:	Added more information and corrected number of overlays.
	v230713:	Added crop-n-save option.
	v230718: 	Deactivated non-working 'rename' operation.
	v230803:	Replaced getDir for 1.54g10. F4: updated function unCleanLabel.
	v240817:	Fixes mislabelling of height at width in dialog. Added bounding coordinates.
*/
	macroL = "Overlay_manager_v240817b.ijm";
	requires("1.53d");
	sliceNumber = getSliceNumber();
	slices = nSlices;
	selEType = selectionType;
	overlayCount = Overlay.size;
	maxLines = round(screenHeight/40);
	if (Overlay.size<1) exit("Sorry, no overlays available");
	sWidth = screenWidth();
	fS = File.separator;
	/*
	The following list adapted from https://imagej.net//macros/Sort-Selections-in-Overlays.txt
	*/
	overlayColors = newArray(overlayCount);
	overlayGroups = newArray(overlayCount);
	overlayHeights = newArray(overlayCount);
	overlayInfo = newArray(overlayCount);
	overlayNames = newArray(overlayCount);
	overlayPoints = newArray(overlayCount);
	overlaySlices = newArray(overlayCount);
	overlayStrokeWidths = newArray(overlayCount);
	overlayTypes = newArray(overlayCount);
	overlayWidths = newArray(overlayCount);
	overlayXs = newArray(overlayCount);
	overlayYs = newArray(overlayCount);
	for (i=0; i<overlayCount; i++) {
		Overlay.activateSelection(i);
		ovlName = getInfo("selection.name");
		if (ovlName=="") overlayNames[i] = "null";
		else overlayNames[i] = getInfo("selection.name");
		overlayColors[i] = getInfo("selection.color");
		overlayGroups[i] = Roi.getGroup;
		getSelectionBounds(overlayXs[i], overlayYs[i], overlayWidths[i], overlayHeights[i]);
		overlayPoints[i] = getValue("selection.size");
		overlayStrokeWidths[i] = Roi.getStrokeWidth;
		overlaySlices[i] = getSliceNumber();
		type = selectionType();
		overlayTypes[i] = "" + convertTypeToString(type, false);
		overlayInfo[i] = "Index = " + i + ", Slice = " + overlaySlices[i] + ", Name = " + overlayNames[i] + ", Group = " + overlayGroups[i] + ", Color = " + overlayColors[i] + ", Stroke Width = " + overlayStrokeWidths[i] + ", X = " + overlayXs[i] + ", Y = " + overlayYs[i] + ", Width = " + overlayWidths[i] + ", Height = " + overlayHeights[i] + ", Type = " +overlayTypes[i] + ", Points = " + overlayPoints[i];
	}
	if (slices>1){
		sliceCounts = newArray(slices);
		for (i=0; i<(overlayCount); i++) {
			sliceCounts[overlaySlices[i]-1] += 1;
		}
	}
	if (overlayCount>maxLines){
		Dialog.create("Reduce range of overlays to manage \(" + macroL + "\)");
			if (slices>1){
				for (i=0; i<slices; i++){
					Dialog.addMessage("In slice " + i+1 + " there are " + sliceCounts[i] + " overlays available to list");
				}
				Dialog.addNumber("Select slice",0,0,4);
			}
			else Dialog.addMessage("There are " + overlayCount + "overlays");
			Dialog.addNumber("Select overlay range start",1,0,4,"");
			Dialog.addNumber("Select overlay range end",maxLines,0,4,"");
		Dialog.show;
			if (slices>1) sliceNumber = Dialog.getNumber;
			oRStart = Dialog.getNumber-1;
			oREnd = Dialog.getNumber-1;
	}
	else {
		oRStart = 0;
		oREnd = overlayCount;
	}	
	setSlice(sliceNumber);
	/*
	Returns to first slice but list of overlays is for all slices 
	*/
	Dialog.create("Manage Current Overlay Selections \(" + macroL + "\)");
	Dialog.addMessage("Current slice: " + sliceNumber + " out of " + slices + " slices.\nBut overlays for ALL slices are listed.");
		Dialog.addMessage("Select overlay selections and operation");
		Dialog.addRadioButtonGroup("Choose operation", newArray("Delete", "Add to ROI Manager", "Move", "Crop-n-save All"), 1, 4, "Delete");
		/* Operations: 'Rename' not currently working */
		Dialog.addCheckbox("Select all?",false);
		for (i=oRStart; i<oREnd; i++)
			Dialog.addCheckbox(overlayInfo[i] , false);
		Dialog.addString("Delete all overlays with names having this string:", "");
		Dialog.addCheckbox("Open 'List Elements' table after processing",false);
	Dialog.show();
		selectionsToChange = newArray(overlayCount);
		checked = 0;
		operation = Dialog.getRadioButton();
		selAll = Dialog.getCheckbox();
		for (i=oRStart; i<oREnd; i++) {
			if (Dialog.getCheckbox==true || selAll==true) {
				selectionsToChange[checked] = i;
				checked += 1;
			}
		}
		wildCardString = Dialog.getString();
		listElements = Dialog.getCheckbox();
	if(!startsWith(operation,"Crop")){
		if ((checked==0) && (wildCardString=="")) exit("No changes requested");
		if (checked!=0) {
			selectionsToChange = Array.trim(selectionsToChange, checked);
			if (operation=="Delete") {
				selectionsToChange = Array.reverse(selectionsToChange); /* Need to remove higher indices first, other index number change */
				for (i = 0; i<checked; i++)
					Overlay.removeSelection(selectionsToChange[i]);
			}
			else if (operation=="Move"){
				Dialog.create("Move Overlay Selections");
				Dialog.addMessage("Move each overlay selections to new x and y below");
				for (i = 0; i<checked; i++) {
					Dialog.addNumber("Overlay selection " + selectionsToChange[i] + " new start x:", 0);
					Dialog.addNumber("Overlay selection " + selectionsToChange[i] + " new start y:", 0);
				}
				Dialog.show();
				for (i = 0; i<checked; i++) {
					x = Dialog.getNumber();
					y = Dialog.getNumber();
					Overlay.moveSelection(selectionsToChange[i], x, y);
				}
			}
			if (operation=="Add to ROI Manager") {
				for (i = 0; i<checked; i++){
					Overlay.activateSelection(selectionsToChange[i]);
					roiManager("add");
					if (overlayNames[i] != "null"){
						j = roiManager("size");
						roiManager("select", j-1);
						roiManager("rename", overlayNames[i]);					
					}
					if (overlayGroups[i] != 0){
						j = roiManager("size");
						roiManager("select", j-1);
						RoiManager.setGroup(overlayGroups[i]);					
					}
				}
			}
			// else if (startsWith(operation,"Rename")){
				// Dialog.create("Rename Overlay Selections");
				// Dialog.addMessage("Sorry, this feature does not work yet\nbut it is harmless if you would like to try it");
				// for (i = 0; i<checked; i++) {
					// Dialog.addString("Overlay selection " + selectionsToChange[i] + " from " + overlayNames[selectionsToChange[i]] + "to:", "");
				// }
				// Dialog.show();
				// for (i = 0; i<checked; i++) {
					// Overlay.activateSelection(selectionsToChange[i]);
					// setSelectionName(Dialog.getString);
				// }
			// }
		}
	}
	else {
		activeDir = getDirectory("image"); /* Returns the path to the directory that the active image was loaded from */
		currentDir = getInfo("image.directory"); /* Returns the directory that the current image was loaded from, or an empty string if the directory is not available */
		openedDir = File.directory; /* The directory path of the last file opened using a file open dialog, a file save dialog, drag and drop, open(path) or runMacro(path). */
		saveDirs = newArray();
		iJPath = getDirectory("imagej");
		if (activeDir!="" && indexOf(activeDir,iJPath)<0) saveDirs = Array.concat(saveDirs,"Active Directory: " + activeDir );
		if (currentDir!="" && currentDir!=activeDir && indexOf(currentDir,iJPath)<0)	saveDirs = Array.concat(saveDirs,"Current Directory: " + currentDir);
		if (openedDir!="" && openedDir!=activeDir && indexOf(openedDir,iJPath)<0) saveDirs = Array.concat(saveDirs,"Last Opened Directory: " + openedDir);
		Dialog.create("Overlay save options \(" +macroL+ "\)");
			fileName = unCleanLabel(stripKnownExtensionFromString(getTitle));
			overlayFileTypes = newArray("tiff","png","jpg","stack_only");
			Dialog.addRadioButtonGroup("Choose output file type:",overlayFileTypes,1,3,overlayFileTypes[0]);
			Dialog.addRadioButtonGroup("Choose output directory or select in dialog below:",saveDirs,saveDirs.length,1,saveDirs[0]);
			Dialog.addDirectory("Select directory:", "");
			Dialog.addString("Create sub-directory:","ROIs",minOf(sWidth-50,lengthOf(fileName)+10));
		Dialog.show;
			overlayOptions = "save ";
			overlayTypeChoice = Dialog.getRadioButton();
			if (overlayTypeChoice!="tiff") overlayOptions += overlayTypeChoice;
			if (startsWith(overlayTypeChoice,"stack")){
				setBatchMode("true");
				Overlay.cropAndSave("", "show");
				setBatchMode("exit and display");
			}
			else {
				dirChoice = Dialog.getRadioButton();
				selDir = Dialog.getString();
				if (selDir!= "") saveDir = selDir;
				else if (startsWith(dirChoice,"Active")) saveDir = activeDir;
				else if (startsWith(dirChoice,"Current")) saveDir = currentDir;
				else if (startsWith(dirChoice,"Last Saved")) saveDir = lastSavedPath;
				else if (startsWith(dirChoice,"Last Opened")) saveDir = openedDir;
				if (!endsWith(saveDir,fS)) saveDir += fS;
				if (!File.isDirectory(saveDir)){
					if (File.exists(saveDir)) exit("Selected directory is a file not a directory");
					else File.makeDirectory(saveDir);
				}
				subDir = Dialog.getString();
				if (subDir!= "") saveDir += fS + subDir + fS;
				if (!File.isDirectory(saveDir)){
					if (File.exists(saveDir)) exit("Selected directory is a file not a directory");
					else File.makeDirectory(saveDir);
				}
				setBatchMode("true");
				Overlay.cropAndSave(saveDir, overlayOptions);
				setBatchMode("exit and display");
			}
	}
	if (wildCardString!="") {
		for (i=0; i<overlayCount; i++){
			Overlay.activateSelection(i);
			overlayName = getInfo("selection.name");
			if (indexOf(overlayName,wildCardString)>=0) Overlay.removeSelection(i);
		}
	}
	run("Select None");
	if (selEType>=0) run("Restore Selection"); 
	if (listElements) run("List Elements");
	/*
		( 8(|)	( 8(|)	ASC Function	@@@@@:-)	@@@@@:-)
	*/
	function convertTypeToString(type, lowercase) {
	/*	v230221 uses array  v231013 added "lowercase" boolean flag and added point type to expand use to selections, and expanded some strings to reflect selection descriptions */
		if(type>10 || type<0) exit("Sorry, " + type + " must be from 0 to 10");
		shapeTypes = newArray("Rectangle", "Oval", "Polygon", "Freehand", "Traced", "Straight Line", "Segmented PolyLine", "Freehand Line", "Angle", "Composite", "Point");
		if (lowercase) return toLowerCase(shapeTypes[parseInt(type)]);
		else return shapeTypes[parseInt(type)];
	}
	function stripKnownExtensionFromString(string) {
		/*	Note: Do not use on path as it may change the directory names
		v210924: Tries to make sure string stays as string.	v211014: Adds some additional cleanup.	v211025: fixes multiple 'known's issue.	v211101: Added ".Ext_" removal.
		v211104: Restricts cleanup to end of string to reduce risk of corrupting path.	v211112: Tries to fix trapped extension before channel listing. Adds xlsx extension.
		v220615: Tries to fix the fix for the trapped extensions ...	v230504: Protects directory path if included in string. Only removes doubled spaces and lines.
		v230505: Unwanted dupes replaced by unusefulCombos.	v230607: Quick fix for infinite loop on one of while statements.
		v230614: Added AVI.	v230905: Better fix for infinite loop. v230914: Added BMP and "_transp" and rearranged
		*/
		fS = File.separator;
		string = "" + string;
		protectedPathEnd = lastIndexOf(string,fS)+1;
		if (protectedPathEnd>0){
			protectedPath = substring(string,0,protectedPathEnd);
			string = substring(string,protectedPathEnd);
		}
		unusefulCombos = newArray("-", "_"," ");
		for (i=0; i<lengthOf(unusefulCombos); i++){
			for (j=0; j<lengthOf(unusefulCombos); j++){
				combo = unusefulCombos[i] + unusefulCombos[j];
				while (indexOf(string,combo)>=0) string = replace(string,combo,unusefulCombos[i]);
			}
		}
		if (lastIndexOf(string, ".")>0 || lastIndexOf(string, "_lzw")>0) {
			knownExts = newArray(".avi", ".csv", ".bmp", ".dsx", ".gif", ".jpg", ".jpeg", ".jp2", ".png", ".tif", ".txt", ".xlsx");
			knownExts = Array.concat(knownExts,knownExts,"_transp","_lzw");
			kEL = knownExts.length;
			for (i=0; i<kEL/2; i++) knownExts[i] = toUpperCase(knownExts[i]);
			chanLabels = newArray(" \(red\)"," \(green\)"," \(blue\)","\(red\)","\(green\)","\(blue\)");
			for (i=0,k=0; i<kEL; i++) {
				for (j=0; j<chanLabels.length; j++){ /* Looking for channel-label-trapped extensions */
					iChanLabels = lastIndexOf(string, chanLabels[j])-1;
					if (iChanLabels>0){
						preChan = substring(string,0,iChanLabels);
						postChan = substring(string,iChanLabels);
						while (indexOf(preChan,knownExts[i])>0){
							preChan = replace(preChan,knownExts[i],"");
							string =  preChan + postChan;
						}
					}
				}
				while (endsWith(string,knownExts[i])) string = "" + substring(string, 0, lastIndexOf(string, knownExts[i]));
			}
		}
		unwantedSuffixes = newArray(" ", "_","-");
		for (i=0; i<unwantedSuffixes.length; i++){
			while (endsWith(string,unwantedSuffixes[i])) string = substring(string,0,string.length-lengthOf(unwantedSuffixes[i])); /* cleanup previous suffix */
		}
		if (protectedPathEnd>0){
			if(!endsWith(protectedPath,fS)) protectedPath += fS;
			string = protectedPath + string;
		}
		return string;
	}
	function unCleanLabel(string) {
	/* v161104 This function replaces special characters with standard characters for file system compatible filenames.
	+ 041117b to remove spaces as well.
	+ v220126 added getInfo("micrometer.abbreviation").
	+ v220128 add loops that allow removal of multiple duplication.
	+ v220131 fixed so that suffix cleanup works even if extensions are included.
	+ v220616 Minor index range fix that does not seem to have an impact if macro is working as planned. v220715 added 8-bit to unwanted dupes. v220812 minor changes to micron and Ångström handling
	+ v231005 Replaced superscript abbreviations that did not work.
	+ v240124 Replace _+_ with +.
	*/
		/* Remove bad characters */
		string = string.replace(fromCharCode(178), "sup2"); /* superscript 2 */
		string = string.replace(fromCharCode(179), "sup3"); /* superscript 3 UTF-16 (decimal) */
		string = string.replace(fromCharCode(0xFE63) + fromCharCode(185), "sup-1"); /* Small hyphen substituted for superscript minus as 0x207B does not display in table */
		string = string.replace(fromCharCode(0xFE63) + fromCharCode(178), "sup-2"); /* Small hyphen substituted for superscript minus as 0x207B does not display in table */
		string = string.replace(fromCharCode(181) + "m", "um"); /* micron units */
		string = string.replace(getInfo("micrometer.abbreviation"), "um"); /* micron units */
		string = string.replace(fromCharCode(197), "Angstrom"); /* Ångström unit symbol */
		string = string.replace(fromCharCode(0x212B), "Angstrom"); /* the other Ångström unit symbol */
		string = string.replace(fromCharCode(0x2009) + fromCharCode(0x00B0), "deg"); /* replace thin spaces degrees combination */
		string = string.replace(fromCharCode(0x2009), "_"); /* Replace thin spaces  */
		string = string.replace("%", "pc"); /* % causes issues with html listing */
		string = string.replace(" ", "_"); /* Replace spaces - these can be a problem with image combination */
		/* Remove duplicate strings */
		unwantedDupes = newArray("8bit", "8-bit", "lzw");
		for (i=0; i<lengthOf(unwantedDupes); i++){
			iLast = lastIndexOf(string, unwantedDupes[i]);
			iFirst = indexOf(string, unwantedDupes[i]);
			if (iFirst!=iLast) {
				string = string.substring(0, iFirst) + string.substring(iFirst + lengthOf(unwantedDupes[i]));
				i = -1; /* check again */
			}
		}
		unwantedDbls = newArray("_-", "-_", "__", "--", "\\+\\+");
		for (i=0; i<lengthOf(unwantedDbls); i++){
			iFirst = indexOf(string, unwantedDbls[i]);
			if (iFirst>=0) {
				string = string.substring(0, iFirst) + string.substring(string, iFirst + lengthOf(unwantedDbls[i]) / 2);
				i = -1; /* check again */
			}
		}
		string = string.replace("_\\+", "\\+"); /* Clean up autofilenames */
		string = string.replace("\\+_", "\\+"); /* Clean up autofilenames */
		/* cleanup suffixes */
		unwantedSuffixes = newArray(" ", "_", "-", "\\+"); /* things you don't wasn't to end a filename with */
		extStart = lastIndexOf(string, ".");
		sL = lengthOf(string);
		if (sL-extStart<=4 && extStart>0) extIncl = true;
		else extIncl = false;
		if (extIncl){
			preString = substring(string, 0, extStart);
			extString = substring(string, extStart);
		}
		else {
			preString = string;
			extString = "";
		}
		for (i=0; i<lengthOf(unwantedSuffixes); i++){
			sL = lengthOf(preString);
			if (endsWith(preString, unwantedSuffixes[i])) {
				preString = substring(preString, 0, sL-lengthOf(unwantedSuffixes[i])); /* cleanup previous suffix */
				i=-1; /* check one more time */
			}
		}
		if (!endsWith(preString, "_lzw") && !endsWith(preString, "_lzw.")) preString = replace(preString, "_lzw", ""); /* Only want to keep this if it is at the end */
		string = preString + extString;
		/* End of suffix cleanup */
		return string;
	}