/* A macro to copy the image scale from one open image to one or more other open images
	Features:	If only one scaled and one unscaled images it automatically transfers the scale to the unscaled image
				Scale can be copied to more than one image
				Images with scales are listed separately and if there is only one it is automatically selected as the source (but are not selected as targets)
				Images with no scale are listed as primary target choices and are automatically selected
	Peter J. Lee Applied Superconductivity Center, NHMFL, Florida State University
	v200922: 1st working version
	v210804-5: Modified to handle large numbers of images.
	v210809: Fixed error on line 88  Updated functions: 5/16/2022 3:43 PM
	v220610: pixel width values of 1 are assumed to be unscaled.  Minor cosmetic fixes. v220614  Allowed more images (based on screen height).
	v220715: Batchmode now working (much faster). Better dialog for larger numbers of open images. v220725 Now correctly lists source image IDs
	v221213: Apparently does need some delay to register each image.
	v230103-4b: Added a diagnostic option to show the progress of scale application by flashing the images and also removed some redundant code.
	v230822:	Corrected selectedImage to selectedWindow
*/
macro "Copy Image Scale" { 
	/* Note that the version used in the startup macro has shortcut key in name */
	macroL = "Copy_Image_Scale_v230822.ijm";
	requires("1.53i"); /* for flashing images */
	imgC = nImages;
	if (imgC==0) exit("No images open.");
	imgTitles = getList("image.titles");
	imgSTitle = getTitle(); /* for default source image */
	imgPxWs = newArray(imgC);
	imgPxHs = newArray(imgC);
	imgPxDs = newArray(imgC);
	imgUs = newArray(imgC);
	screenH = screenHeight;
	screenW = screenWidth;
	maxImgs = round(screenH/40);
	iSourceImgs = newArray(); /* Images that have a scale so can be sources */
	iNoScaleImgs = newArray(); /* Images that have no scale so they cannot be sources */
	if (imgC<6){
		showProg = true;
		setBatchMode(true); /* Only to the 1st Dialog */
	}
	else showProg = false;
	showTime = 2000/imgC;
	iDefSImg = -1;
	for (i=0,imgScaleC=0,noImgScaleC=0; i<imgC; i++) {
		selectWindow(imgTitles[i]); /* image windows are numbered sequentially in integers from 1 upwards */
		/* now populate data arrays one by one */
		getVoxelSize(imgPxWs[i], imgPxHs[i], imgPxDs[i], imgUs[i]);
		/* Now assume that if there is no unit there is no scale so this must be a target not a source */
		if (imgUs[i]=="pixels" || imgPxWs[i]==1 || imgUs[i]==""){
			iNoScaleImgs[noImgScaleC] = i;
			noImgScaleC++; /* count the number of images without a scale - these cannot be source images */
			if (showProg){
				showStatus("No image scale for " + imgTitles[i], "flash image red " + showTime + "mS");
				wait(showTime);
			}
		}
		else {  /* if there is a unit then this can be a source (or a target) */
			if (imgTitles[i]==imgSTitle) iDefSImg = i; /* for default source image */
			iSourceImgs[imgScaleC] = d2s(i,0); /* converted to string for radiobuttongroup */
			imgScaleC++; /* Count the number of images with a scale so that the source array can be trimmed */
			if (showProg){
				showStatus("Image scale retrieved for " + imgTitles[i], "flash image green " + showTime + "mS");
				wait(showTime);
			}
		}
	}
	imgTotal = imgScaleC + noImgScaleC;
	if (imgScaleC==1 && noImgScaleC==0) /* The only images open already has a scale */
		exit ("Nothing to do; the only image open already has a scale");
	else if (imgTotal < imgC) exit("Only " + imgTotal + " images out of " + imgC + "were checked for some reason, please report error");
	else if (imgScaleC==0) exit("No open images have scales to copy");
	if (iDefSImg<0) iDefSImg = iSourceImgs[0];
	if (imgScaleC==1 && noImgScaleC==1) { /* Only one source and one target image so no decisions necessary */
		sAI = iSourceImgs[0];
		selectWindow(imgTitles[iNoScaleImgs[0]]);
		setVoxelSize(imgPxWs[sAI], imgPxHs[sAI], imgPxDs[sAI], imgUs[sAI]);
		showStatus("Scale auto-copied from scaled to unscaled image", "flash image green " + showTime + "mS");
	}
	else if (imgC>maxImgs){
		setBatchMode("exit and display");
		Dialog.create(macroL + ": Apply current scale to all other open images");
			Dialog.addMessage(imgC + " images open, the current menu is limited to " + maxImgs);
			imgWidthU = getWidth() * imgPxWs[imgIDCi];
			Dialog.addMessage("Current image title: " + imgTitles[iDefSImg] + ", width: " + imgWidthU + " " +  imgUs[iDefSImg]
			+ "\nCurrent image pixel width: " + imgPxWs[iDefSImg] + " " + imgUs[iDefSImg]
			+ "\nCurrent image pixel height: " + imgPxHs[iDefSImg] + " " + imgUs[iDefSImg]);
			Dialog.addCheckbox("Copy scale from current image to all other open images?",true);
			if (imgScaleC>1) Dialog.addCheckbox("Overwrite existing scales?",false);
			Dialog.addCheckbox("Show progress \(slows things down a bit\)",showProg);
		Dialog.show();
		copyToAll = Dialog.getCheckbox();
		showProg = Dialog.getCheckbox();
		if (!copyToAll) exit("Goodbye");
		if (imgScaleC>1) copyToAllOv = Dialog.getCheckbox();
		for (i=0; i<imgC; i++){
			if (i!=iDefSImg){
				if (copyToAllOv || imgUs[i]=="pixel") {
					// tII = iNoScaleImgs[i];
					selectWindow(imgTitles[i]);
					setVoxelSize(imgPxWs[iDefSImg], imgPxHs[iDefSImg], imgPxDs[iDefSImg], imgUs[iDefSImg]);
					if(showProg) showStatus("Image scale applied to " + getTitle(), "flash image green " + showTime + "mS");
				}
			}
		}
	}	
	else {
		setBatchMode("exit and display");
		Dialog.create(macroL + ": Select source and target images");
			Dialog.addMessage(imgC + " images open, " + imgScaleC + " with scale and " + noImgScaleC + " without");
			Dialog.addCheckbox("Show progress \(slows things down a bit\)",showProg);
			/* Provide source image selection */
			if (imgScaleC==1){
				Dialog.addMessage("Source image:__________________");
				imgISInfoLine = "" + i + ": " + imgTitles[iDefSImg];
					if (imgPxWs[iDefSImg]==imgPxHs[iDefSImg] && imgPxHs[iDefSImg]==imgPxDs[iDefSImg]) imgISInfoLine += ", pixel xyz size = " +  imgPxHs[iDefSImg] + " " + imgUs[iDefSImg];
					else imgISInfoLine += ", pixel xyz dimensions = " + imgPxWs[iDefSImg] + "," + imgPxHs[iDefSImg] + "," + imgPxDs[iDefSImg] + " " + imgUs[iDefSImg];				
				Dialog.setInsets(-5, 0, 0);
				Dialog.addMessage(imgISInfoLine);
				}
			else {
				Dialog.addMessage("Images that already have scales set:_______________");
				imgISInfo = "";
				for (i=0,maxString=0; i<imgScaleC; i++) {
					sN = iSourceImgs[i];
					imgISInfoLine = "" + sN + ": " + imgTitles[sN];
					if (imgPxWs[sN]==imgPxHs[sN] && imgPxHs[sN]==imgPxDs[sN]) imgISInfoLine += ", pixel xyz size = " +  imgPxHs[sN] + " " + imgUs[sN];
					else imgISInfoLine += ", pixel xyz dimensions = " + imgPxWs[sN] + "," + imgPxHs[sN] + "," + imgPxDs[sN] + " " + imgUs[sN];
					stringL = lengthOf(imgISInfoLine);
					if(stringL>maxString) maxString = stringL;
					if (i<imgScaleC-1) imgISInfoLine + = "\n";
					imgISInfo += imgISInfoLine;
				}
				Dialog.addMessage(imgISInfo);
				Dialog.addRadioButtonGroup("Select scale source image from list above:",iSourceImgs,round(imgScaleC/10),10,iDefSImg);
			}
			/* Provide target image selection(s) */
			if (noImgScaleC>0){
				imgNSInfo = "";
				Dialog.addMessage("Target image\(s\) without scale:");
				if (noImgScaleC>1) Dialog.addCheckbox("Select all " + noImgScaleC + " images without scale \(overrides selections below\)", false);
				targetNSCheckBoxGroup = newArray();
				imgNSInfoLine = "";
				imgNSInfo = "";
				for (i=0,maxString=0; i<noImgScaleC; i++){
					tN = iNoScaleImgs[i];
					imgNSInfoLine = "" + tN + ": " + imgTitles[tN];
					targetNSCheckBoxGroup = Array.concat(targetNSCheckBoxGroup,d2s(tN,0));
					stringL = lengthOf(imgNSInfoLine);
					if(stringL>maxString) maxString = stringL;
					if (i<noImgScaleC-1) imgNSInfoLine + = "\n";
					imgNSInfo += imgNSInfoLine;
				}
				Dialog.addMessage(imgNSInfo);		
				targetNSDefaults = Array.fill(newArray(noImgScaleC),true);
				Dialog.setInsets(5,20,0);
				Dialog.addCheckboxGroup(maxOf(1,round(noImgScaleC/10)),10,targetNSCheckBoxGroup, targetNSDefaults); /* Dialog.addCheckboxGroup(rows, columns, labels, defaults)  */
			}
			if (imgScaleC>1){
				Dialog.addMessage("Target image\(s\) that already have a scale:_______________");
				Dialog.addCheckbox("Select all " + imgScaleC + "  images with scale \(overrides selections below\)", false);
				targetISCheckBoxGroup = newArray();
				for (i=0; i<imgScaleC; i++) {
					/* Don't generate title and image information again as that is already listed in the potential source section */
					sN = iSourceImgs[i];
					targetISCheckBoxGroup = Array.concat(targetISCheckBoxGroup,d2s(sN,0));
				}
				targetISDefaults = Array.fill(newArray(imgScaleC),false);
				Dialog.addMessage("Choose to overide scales in image\(s\) with scale listed in first section:");
				Dialog.setInsets(5,20,0);
				Dialog.addCheckboxGroup(maxOf(1,round(imgScaleC/10)),10,targetISCheckBoxGroup, targetISDefaults);
			}
		Dialog.show();
			showProg = Dialog.getCheckbox();
			if (imgScaleC==1)	sII = iSourceImgs[0];
			else sII = parseInt(Dialog.getRadioButton()); /* works fine without parseInt but this could avoid issues in the future */
			sPixelWidth = imgPxWs[sII];
			sPixelHeight = imgPxHs[sII];
			sPixelDepth = imgPxDs[sII];
			sPixelUnit = imgUs[sII];
			/* Provide target image selection(s) */
			tImgs = newArray();
			tempTImgs = newArray();
			if(!showProg) setBatchMode("true");
			if (noImgScaleC>0){
				if (noImgScaleC>1) targetAllNSImgs = Dialog.getCheckbox();
				else targetAllNSImgs = false;
				for (i=0; i<noImgScaleC; i++) if(Dialog.getCheckbox()) tempTImgs = Array.concat(tempTImgs,targetNSCheckBoxGroup[i]);
				if (targetAllNSImgs) tImgs = targetNSCheckBoxGroup;
				else tImgs = tempTImgs;
				tempTImgs = newArray();
			}
			if (imgScaleC>1){
				targetAllSImgs = Dialog.getCheckbox();
				for (i=0; i<imgScaleC; i++) if(Dialog.getCheckbox()) tempTImgs = Array.concat(tempTImgs,targetISCheckBoxGroup[i]);
				if (targetAllSImgs) tImgs = Array.concat(tImgs,targetISCheckBoxGroup);
				else tImgs = Array.concat(tImgs,tempTImgs);
			}
		/* End 'Select source and target images' Dialog */
		targetN = tImgs.length;
		if (targetN<1) exit("No target images selected");
		else {
			for (i=0; i<targetN; i++) {
				iTargetImg = parseInt(tImgs[i]);
				selectWindow(imgTitles[iTargetImg]);
				setVoxelSize(sPixelWidth, sPixelHeight, sPixelDepth, sPixelUnit);
				if(showProg) showStatus("Image scale applied to " + imgTitles[iTargetImg], "flash image green " + showTime + "mS");
			}
		}
	}
	setBatchMode("exit and display");
	showStatus("Scale copy macro completed");
}