/*	Create table of statistic from Results table using array statistics
*	Peter J. Lee - NHMFL - This version: v160809
	v211117 Updated functions
*/
macroL = "Summary_Statistics_Table_v211117.ijm";
setBatchMode(true);
N = nResults;

if (N==0) {
	showMessageWithCancel("No results to play with  ¯|_(?)_/¯","This macro requires a results table and will proceed with the Blobs demo instead.");
	if (isOpen("blobs.gif")) selectWindow("blobs.gif");
	else run("Blobs (25K)");
	run("Make Binary");
	run("Analyze Particles...", "size=0-Infinity circularity=0.00-1.00 show=Nothing display exclude");
}
N = nResults;
imageTitle = getTitle();
dirImage = getDirectory("image");
stats = newArray(
 "N",
 "Sum",
 "Mean",
 "Median",
 "StdDev\(sample\)",
 "CoeffVar\(%\)",
 "SE","95% CI",
 "Min","Max",
 "Range",
 "IQR",
 "Scott's Bin size",
 "FD Bin Size",
 "log stats mean",
 "log stats -stdDev",
 "log stats +stdDev",
 "log stats -coeffVar\(%\)",
 "log stats +coeffVar\(%\)");

cleanUp(); /* Before ROI manager check */
headings = split(String.getResultsHeadings);
for (i=0; i<lengthOf(headings); i++) {
	showProgress(i, lengthOf(headings));
	if (i>0) {
		hideResultsAs("Statistical_Summary");
		restoreResultsFrom("Results_Main");
	}
	resultsArray = newArray(N);
	logResultsArray = newArray(N);
	for (r=0; r<N; r++) {
		resultsArray[r] = getResult(headings[i], r);
		logResultsArray[r] = log(resultsArray[r]);
	}
	sortedValues = Array.copy(resultsArray);
	sortedValues = Array.sort(sortedValues);
	Array.getStatistics(resultsArray, arrayMin, arrayMax, arrayMean, arraySD); 
	// variance = arraySD * arraySD; // 
	SE = (arraySD/(sqrt(N))); // Standard Error
	CI95 = 1.96 * SE; // two-sided confidence level
	range = arrayMax - arrayMin;
	IQR = resultsArray[round(N * 0.75)]-resultsArray[round(N * 0.25)];
	ScottsBin = 3.5 * arraySD/pow(N, 1 / 3); // bin size by Scott' normal reference rule: https://en.wikipedia.org/wiki/Histogram
	FDBin = 2 * IQR / pow(N, 1 / 3); //  Freedman–Diaconis rule: https://en.wikipedia.org/wiki/Freedman%E2%80%93Diaconis_rule
	// now log Stats
	Array.getStatistics(logResultsArray, logArrayMin, logArrayMax, logArrayMean, logArraySD); 
	logStatMean = exp(logArrayMean);
	logStatSD = exp(logArraySD);
	logStatMeanD = exp(logArrayMean - logArraySD);
	logStatMeanU = exp(logArrayMean + logArraySD);	
	logStatsMeanMinusStdDev = logStatMean - exp(logArrayMean - logArraySD);
	logStatsMeanPlusStdDev = exp(logArrayMean + logArraySD) - logStatMean;
	
// 	Add results to statistics table	
	hideResultsAs("Results_Main");
	if(i==0) {
		for (j=0; j<lengthOf(stats); j++) 
			setResult("Summary", j, stats[j]);
	}		
	else restoreResultsFrom("Statistical_Summary");
	setResult(headings[i], 0, round(N));
	setResult(headings[i], 1, arrayMean * N);
	setResult(headings[i], 2, arrayMean);
	setResult(headings[i], 3, sortedValues[round(N/2)]);
	setResult(headings[i], 4, arraySD);
	setResult(headings[i], 5, (100/arrayMean) * arraySD);
	setResult(headings[i], 6, SE);
	setResult(headings[i], 7, CI95);
	setResult(headings[i], 8, arrayMin);
	setResult(headings[i], 9, arrayMax);
	setResult(headings[i], 10, range);
	setResult(headings[i], 11, IQR); // interquartile range
	setResult(headings[i], 12, ScottsBin);
	setResult(headings[i], 13, FDBin);
	setResult(headings[i], 14, logStatMean);
	setResult(headings[i], 15, logStatsMeanMinusStdDev);
	setResult(headings[i], 16, logStatsMeanPlusStdDev);
	setResult(headings[i], 17, (100/logStatMean) * logStatsMeanMinusStdDev);
	setResult(headings[i], 18, (100/logStatMean) * logStatsMeanPlusStdDev);
	updateResults();
}
// stats are "N","Sum","Mean","Median","StdDev\(sample\)", "CoeffVar\(%\)", "SE","95% CI","Min","Max", "Range", "IQR", "Scott's Bin size", "FD Bin Size", "log stats mean", "log stats -stdDev", "log stats +stdDev", "log stats -coeffVar\(%\)", "log stats +coeffVar\(%\)");
	saveExcelFile(dirImage, imageTitle + "_stats", "Results"); 
	closeNonImageByTitle("Results");
	restoreResultsFrom("Results_Main");
	setBatchMode("exit & display"); /* exit batch mode */
	
	/* ( 8(|)   ( 8(|)  ASC Functions  ( 8(|)  ( 8(|)   */
	
	function cleanUp() { //cleanup leftovers from previous runs
		restoreResultsFrom("Results_Main");
		closeNonImageByTitle("Statistical_Summary");
	}
	function closeNonImageByTitle(windowTitle) {
	/*  v200925 uses "while" instead of if so it can also remove duplicates
	*/
		while (isOpen(windowTitle)) {
			selectWindow(windowTitle);
			run("Close");
		}
	}
	function getDateCode() {
		/* v170823 */
		getDateAndTime(year, month, dayOfWeek, dayOfMonth, hour, minute, second, msec);
		month = month + 1; /* Month starts at zero, presumably to be used in array */
		if(month<10) monthStr = "0" + month;
		else monthStr = ""  + month;
		if (dayOfMonth<10) dayOfMonth = "0" + dayOfMonth;
		dateCodeUS = monthStr+dayOfMonth+substring(year,2);
		return dateCodeUS;
	}
	function hideResultsAs(deactivatedResults) {
		if (isOpen("Results")) {  /* This swapping of tables does not increase run time significantly */
			selectWindow("Results");
			IJ.renameResults(deactivatedResults);
		}
	}
	function restoreResultsFrom(deactivatedResults) {
		if (isOpen(deactivatedResults)) {
			selectWindow(deactivatedResults);		
			IJ.renameResults("Results");
		}
	}
	function saveExcelFile(outputDir, outputName, outputResultsTable) {
	/* v190116 corrected typo in resultsPath */
		selectWindow(outputResultsTable);
		resultsPath = outputDir + outputName + "_" + outputResultsTable + "_" + getDateCode() + ".csv"; /* CSV behaves better with Excel 2016 than XLS */
		if (File.exists(resultsPath)==0)
			saveAs("Results", resultsPath);
		else {
			overWriteFile=getBoolean("Do you want to overwrite " + resultsPath + "?");
			if(overWriteFile==1)
					saveAs("Results", resultsPath);
		}		
	}