/*	Simple macro to plot 2 columns from the active table.
	Inspired even simpler macro by Kees Straatman https://www2.le.ac.uk/colleges/medbiopsych/facilities-and-services/cbs/AIF/software-1/imagej-macros#Plot%20results
	1st version 082319
	v211022 Updated color choices  f1-3: updated functions f4-6 updated colors. F7: getColorArrayFromColorName_v230908.
	v231013: Table headers only split by tabs. F1: Replaced function: pad. F2: Updated getColorFromColorName function (012324).
	v240402: Added axis title option.
*/
macro Quick_plot_2_Table_Columns {
	requires("1.52a");
	macroL = "QuickPlot_2_TableColumns_v240402.ijm";
	saveSettings(); /* To restore settings at the end */
	run("Plots...", "width=512 height=384 font=14 draw draw_ticks");
 	headings = split(Table.headings, "\t");
	sortChoices = newArray("no","ascending","descending");
	types = newArray( "dot","line","connected circle","filled","bar","separated bar","circle","box","triangle","diamond","cross", "x");
	colorChoicesStd = newArray("red", "green", "blue", "cyan", "magenta", "yellow", "pink", "orange", "violet");
	colorChoicesMod = newArray("garnet", "gold", "aqua_modern", "blue_accent_modern", "blue_dark_modern", "blue_modern", "blue_honolulu", "gray_modern", "green_dark_modern", "green_modern", "green_modern_accent", "green_spring_accent", "orange_modern", "pink_modern", "purple_modern", "red_n_modern", "red_modern", "tan_modern", "violet_modern", "yellow_modern");
	colorChoicesNeon = newArray("jazzberry_jam", "radical_red", "wild_watermelon", "outrageous_orange", "supernova_orange", "atomic_tangerine", "neon_carrot", "sunglow", "laser_lemon", "electric_lime", "screamin'_green", "magic_mint", "blizzard_blue", "dodger_blue", "shocking_pink", "razzle_dazzle_rose", "hot_magenta");
	colorChoices = Array.concat("black", colorChoices, colorChoicesStd, colorChoicesMod, colorChoicesNeon);
 	Dialog.create("Choose Y and X Columns");
		Dialog.addMessage("Macro: " + macroL);
		Dialog.addMessage("Additional data and formatting can be added from the built-in plot menu");
 		Dialog.addChoice("Select the results for the X axis", headings, headings[0]);
 		Dialog.addChoice("Select the results for the Y axis", headings, headings[1]);
		Dialog.addString("X-axis title \(if different from selected columnn name\)", "", 20);
		Dialog.addString("Y-axis title \(if different from selected columnn name\)", "", 20);
		Dialog.addString("Plot title \(if different from auto-generated\)", "", 20);
		Dialog.addCheckbox("Sort XY pairs by ascending X values?",true);
		Dialog.addChoice("Select plot type", types, types[2]);
		Dialog.addChoice("Select the plot color", colorChoices, "black");
		Dialog.addChoice("Select the color filling symbols or connecting line", colorChoices, "black");
		Dialog.addNumber("Choose line width",2,0,2,"pixels");
		// Dialog.addCheckbox("Log X scale?",false);
		// Dialog.addCheckbox("Log Y scale?",false);
 	Dialog.show();
		xChoice = Dialog.getChoice;
		yChoice = Dialog.getChoice;
		xTitle = Dialog.getString();
		if (xTitle=="") xTitle = xChoice;
		yTitle = Dialog.getString();
		if (yTitle=="") yTitle = yChoice;
		plotTitle = Dialog.getString;
		if (plotTitle=="") plotTitle = xTitle + "-" + yTitle;
		xSort = Dialog.getCheckbox;
		type = Dialog.getChoice;
		plotColor = Dialog.getChoice;
		plotColor2 = Dialog.getChoice;
		lineWidth = Dialog.getNumber;
		// logX = Dialog.getCheckbox;
		// logY = Dialog.getCheckbox;
 	xValues = Table.getColumn(xChoice);
 	yValues = Table.getColumn(yChoice);
	if (xSort){
		rankXs = Array.rankPositions(xValues);
		xValues = Array.sort(xValues);
		yValuesSorted = newArray(yValues.length);
		for (i=0; i<yValues.length; i++) yValuesSorted[i] = rankXs[i];
		yValues = yValuesSorted;
	}
	Plot.create(plotTitle, xTitle, yTitle);
	// if (logX) Plot.setLogScaleX();
	// if (logY) Plot.setLogScaleY();
	Plot.setColor(getHexColorFromColorName(plotColor), getHexColorFromColorName(plotColor2));
	Plot.setLineWidth(lineWidth);
 	Plot.add(type, xValues, yValues);
 	Plot.show()
	restoreSettings();
}
	function getColorArrayFromColorName(colorName) {
		/* v180828 added Fluorescent Colors
		   v181017-8 added off-white and off-black for use in gif transparency and also added safe exit if no color match found
		   v191211 added Cyan
		   v211022 all names lower-case, all spaces to underscores v220225 Added more hash value comments as a reference v220706 restores missing magenta
		   v230130 Added more descriptions and modified order.
		   v230908: Returns "white" array if not match is found and logs issues without exiting.
		   v240123: Removed duplicate entries: Now 53 unique colors 
		*/
		functionL = "getColorArrayFromColorName_v240123";
		cA = newArray(255,255,255); /* defaults to white */
		if (colorName == "white") cA = newArray(255,255,255);
		else if (colorName == "black") cA = newArray(0,0,0);
		else if (colorName == "off-white") cA = newArray(245,245,245);
		else if (colorName == "off-black") cA = newArray(10,10,10);
		else if (colorName == "light_gray") cA = newArray(200,200,200);
		else if (colorName == "gray") cA = newArray(127,127,127);
		else if (colorName == "dark_gray") cA = newArray(51,51,51);
		else if (colorName == "red") cA = newArray(255,0,0);
		else if (colorName == "green") cA = newArray(0,255,0);					/* #00FF00 AKA Lime green */
		else if (colorName == "blue") cA = newArray(0,0,255);
		else if (colorName == "cyan") cA = newArray(0, 255, 255);
		else if (colorName == "yellow") cA = newArray(255,255,0);
		else if (colorName == "magenta") cA = newArray(255,0,255);				/* #FF00FF */
		else if (colorName == "pink") cA = newArray(255, 192, 203);
		else if (colorName == "violet") cA = newArray(127,0,255);
		else if (colorName == "orange") cA = newArray(255, 165, 0);
		else if (colorName == "garnet") cA = newArray(120,47,64);				/* #782F40 */
		else if (colorName == "gold") cA = newArray(206,184,136);				/* #CEB888 */
		else if (colorName == "aqua_modern") cA = newArray(75,172,198);		/* #4bacc6 AKA "Viking" aqua */
		else if (colorName == "blue_accent_modern") cA = newArray(79,129,189); /* #4f81bd */
		else if (colorName == "blue_dark_modern") cA = newArray(31,73,125);	/* #1F497D */
		else if (colorName == "blue_honolulu") cA = newArray(0,118,182);		/* Honolulu Blue #006db0 */
		else if (colorName == "blue_modern") cA = newArray(58,93,174);			/* #3a5dae */
		else if (colorName == "gray_modern") cA = newArray(83,86,90);			/* bright gray #53565A */
		else if (colorName == "green_dark_modern") cA = newArray(121,133,65);	/* Wasabi #798541 */
		else if (colorName == "green_modern") cA = newArray(155,187,89);		/* #9bbb59 AKA "Chelsea Cucumber" */
		else if (colorName == "green_modern_accent") cA = newArray(214,228,187); /* #D6E4BB AKA "Gin" */
		else if (colorName == "green_spring_accent") cA = newArray(0,255,102);	/* #00FF66 AKA "Spring Green" */
		else if (colorName == "orange_modern") cA = newArray(247,150,70);		/* #f79646 tan hide, light orange */
		else if (colorName == "pink_modern") cA = newArray(255,105,180);		/* hot pink #ff69b4 */
		else if (colorName == "purple_modern") cA = newArray(128,100,162);		/* blue-magenta, purple paradise #8064A2 */
		else if (colorName == "jazzberry_jam") cA = newArray(165,11,94);
		else if (colorName == "red_n_modern") cA = newArray(227,24,55);
		else if (colorName == "red_modern") cA = newArray(192,80,77);
		else if (colorName == "tan_modern") cA = newArray(238,236,225);
		else if (colorName == "violet_modern") cA = newArray(76,65,132);
		else if (colorName == "yellow_modern") cA = newArray(247,238,69);
		/* Fluorescent Colors https://www.w3schools.com/colors/colors_crayola.asp */
		else if (colorName == "radical_red") cA = newArray(255,53,94);			/* #FF355E */
		else if (colorName == "wild_watermelon") cA = newArray(253,91,120);	/* #FD5B78 */
		else if (colorName == "shocking_pink") cA = newArray(255,110,255);		/* #FF6EFF Ultra Pink */
		else if (colorName == "razzle_dazzle_rose") cA = newArray(238,52,210);	/* #EE34D2 */
		else if (colorName == "hot_magenta") cA = newArray(255,0,204);			/* #FF00CC AKA Purple Pizzazz */
		else if (colorName == "outrageous_orange") cA = newArray(255,96,55);	/* #FF6037 */
		else if (colorName == "supernova_orange") cA = newArray(255,191,63);	/* FFBF3F Supernova Neon Orange*/
		else if (colorName == "sunglow") cA = newArray(255,204,51);			/* #FFCC33 */
		else if (colorName == "neon_carrot") cA = newArray(255,153,51);		/* #FF9933 */
		else if (colorName == "atomic_tangerine") cA = newArray(255,153,102);	/* #FF9966 */
		else if (colorName == "laser_lemon") cA = newArray(255,255,102);		/* #FFFF66 "Unmellow Yellow" */
		else if (colorName == "electric_lime") cA = newArray(204,255,0);		/* #CCFF00 */
		else if (colorName == "screamin'_green") cA = newArray(102,255,102);	/* #66FF66 */
		else if (colorName == "magic_mint") cA = newArray(170,240,209);		/* #AAF0D1 */
		else if (colorName == "blizzard_blue") cA = newArray(80,191,230);		/* #50BFE6 Malibu */
		else if (colorName == "dodger_blue") cA = newArray(9,159,255);			/* #099FFF Dodger Neon Blue */
		else IJ.log(colorName + " not found in " + functionL + ": Color defaulted to white");
		return cA;
	}
	/* Hex conversion below adapted from T.Ferreira, 20010.01 https://imagej.net/doku.php?id=macro:rgbtohex */
	function getHexColorFromColorName(colorNameString) {
		/* v231207: Uses IJ String.pad instead of function: pad */
		colorArray = getColorArrayFromColorName(colorNameString);
		 r = toHex(colorArray[0]); g = toHex(colorArray[1]); b = toHex(colorArray[2]);
		 hexName= "#" + "" + String.pad(r, 2) + "" + String.pad(g, 2) + "" + String.pad(b, 2);
		 return hexName;
	}